Running Siebel Tools 8.x And IE 11 And Win7 x64!

Hi,

I use Win 7 x64 as my development platform, i Develop on Siebel 8.2.2.4, I use IE 11. I’m heading for trouble thats for sure! 🤣😂

Allthough not perfect / not fully tested yet: this is a nice teaser:

Continue reading “Running Siebel Tools 8.x And IE 11 And Win7 x64!”

Siebel ST Scripting Engine – and ECMAScript Compliance

Hi,

Do you ever write eScript in Siebel ???

With never versions of Siebel (7.8+) Siebel introduced the ST Scripting engine. It contains a lot of changes, and Siebel may have jumped the gun a little by actually supporting ECMAScript revision 4, before the standard was finalized, but the information about the compliance is not to be found anywhere in the documentation, or supportweb….

I recently had the chance to discuss the subject with a very knowledgeable Support Engineer, that i have had the pleasure of working with on many occasions. Here´s his reply to my question:

Q) “Which version of ECMA-262 is Siebel eScript based on?”   

A) “Siebel eScript in Siebel 8.x is based on ECMA-262 version 4. This version actually never made it past the proposal status, as mentioned on Wikipedia:
http://en.wikipedia.org/wiki/Ecmascript#ECMAScript.2C_4th_Edition

This fourth edition proposal contained new language features like static typing, which were adopted by Siebel eScript, to make scripts faster and also more robust against the typical programming errors associated with dynamic typing.

While the ECMA-262 version 4 proposal has vanished, eScript continues to provide these new features.

Siebel eScript does adhere to ECMA-262 as much as possible, but subtle differences may always occur, and this is more likely for ECMAScript features that are not documented in Siebel Bookshelf.”

Here is a link to the standards definition (note that this may or may not be the features supported by the Siebel implementation of ECMAScript 4…).

Enjoy!

/Henrik

Using Subversion with Siebel Tools

I’ve for as long as i can remember been using SourceSafe integration for all my siebel projects. Thats all good and fine, but it is aging, and for other projects I’m now using subversion. So when i installed a complete siebel 8.2.2.4, i decided to move the source control integration from SourceSafe to SVN.

First off, Siebel is not really heping you here, the default source control file installed with 8.2.2.4 looks like the source control file back in Siebel 6.

Researching a little on the net, provided lots of discussions if siebel can integrate with SVN, and the answer to that question is yes – it can. But if you come from a development background that is non siebel, then I might as well call it as it is, the source integration will only cover objects modified directly in tools, and it is solely a change log, allowing you to backtrack changes in time to a specific object. Its not a build repository, or even a complete picture of the changes that may be within one version of Siebel (ie. non-metadata changes are not included).

The batch file srcctrl.bat needs a lot of modification to work, luckily there was this one guy Michael Williams, who posted a good looking svn enabled srcctrl.bat file.

Use the file below as your starting point.

@echo off 
SETLOCAL
set SOFTWARE=svn
set CHECKIN=%SOFTWARE% commit
set CHECKOUT=%SOFTWARE% checkout
set ADD=%SOFTWARE% add
rem ==================================================================
rem =============== User defined parameters ==========================
rem ==================================================================  
rem IF SVN IS NOT IN THE DEFAULT PATH ADD IT HERE set PATH=[Path_to_svn];%PATH%
set SVN_URL=https://[svnserver]/svn/[repository]
set SVN_REPOS=[trunk]
set SRC_USR=[youruser]
set SRC_PSWD=[yourpassword]
set LOGFILE=[path_to_siebel_root]\SVN\[repository]\svn_integration.log
set WORKING_DIR=[path_to_siebel_root]\SVN\[repository]
rem LOGFILE SHOULD NOT HAVE SPACES IN ITS PATH 
rem AND WATCH OUT FOR TRAILING SPACES ON THE SET COMMANDS! 
rem ================================================================== 
rem ==================================================================     
set OPTIONS=--username %SRC_USR% --password %SRC_PSWD%
set COMMENT=-F
set FILE=
echo ===========================START============================ >> %LOGFILE%   
echo %DATE% %TIME% >> %LOGFILE%   
echo ARGS: >> %LOGFILE%   
echo %* >> %LOGFILE%
echo ============================================================ >> %LOGFILE%   
echo PARSING.. >> %LOGFILE%   
set ACTION=%1
shift 
set DIR=%1
shift
set COMMENT=%COMMENT% %1
set COMMENT_FILE=%1
shift
set FILE=%1
SET DIR_NO_QUOTE=###%DIR%###
SET DIR_NO_QUOTE=%DIR_NO_QUOTE:"###=%
SET DIR_NO_QUOTE=%DIR_NO_QUOTE:###"=%
SET DIR_NO_QUOTE=%DIR_NO_QUOTE:###=%
if errorlevel 100 goto END   

echo ACTION: %ACTION% >> %LOGFILE%   
echo DIR: %DIR% >> %LOGFILE%   
echo COMMENT_FILE: %COMMENT_FILE% >> %LOGFILE%   
echo FILE: %FILE% >> %LOGFILE%   
echo DIR_NO_QUOTE: %DIR_NO_QUOTE% >> %LOGFILE%   
echo ============================================================ >> %LOGFILE%   

if %ACTION%==checkout goto CHECK_OUT 
if %ACTION%==checkin goto CHECK_IN   

:CHECK_OUT 
echo =========================CHECKOUT=========================== >> %LOGFILE%   
echo Check out file: %FILE% from Source Control System >> %LOGFILE%   
echo Change local directory to %DIR% >> %LOGFILE% 
chdir %DIR% >> %LOGFILE% 2>&1   
echo Start checking out %FILE% from Source Control System >> %LOGFILE% 
echo %CHECKOUT% %SVN_URL%/%SVN_REPOS% %OPTIONS% "%WORKING_DIR%\%SVN_REPOS%" >> %LOGFILE% 
%CHECKOUT% %SVN_URL%/%SVN_REPOS% %OPTIONS% "%WORKING_DIR%\%SVN_REPOS%" >> %LOGFILE% 2>&1   
echo ======================CHECKOUT DONE========================= >> %LOGFILE%   
goto END   

:CHECK_IN 
echo =========================CHECKIN============================ >> %LOGFILE%   
echo Check in file: %FILE% into Source Control System >> %LOGFILE%   
echo Change local directory to %WORKING_DIR%\%SVN_REPOS% >> %LOGFILE% 
chdir %WORKING_DIR%\%SVN_REPOS% >> %LOGFILE% 2>&1   
if exist %FILE% goto FILE_EXIST >> %LOGFILE% 2>&1   
echo Copying %FILE% to local Working Copy Folder: %WORKING_DIR%\%SVN_REPOS% >> %LOGFILE% 
copy "%DIR_NO_QUOTE%%FILE%" "%WORKING_DIR%\%SVN_REPOS%\%FILE%" >> %LOGFILE% 2>&1   
echo Add %FILE% in case it doesn't exist in Source Control System >> %LOGFILE% 
echo %ADD% %WORKING_DIR%\%SVN_REPOS%\%FILE% %OPTIONS% >> %LOGFILE% 
%ADD% %WORKING_DIR%\%SVN_REPOS%\%FILE% %OPTIONS% >> %LOGFILE% 2>&1
goto COMMIT   

:FILE_EXIST   
echo Copying %FILE% to local Working Copy Folder: %WORKING_DIR%\%SVN_REPOS% >> %LOGFILE% 
echo copy "%DIR_NO_QUOTE%%FILE%" "%WORKING_DIR%\%SVN_REPOS%\%FILE%" >> %LOGFILE% 
copy "%DIR_NO_QUOTE%%FILE%" "%WORKING_DIR%\%SVN_REPOS%\%FILE%" >> %LOGFILE% 2>&1
:COMMIT 
echo Check in %WORKING_DIR%\%SVN_REPOS%\%FILE% into Source Control System >> %LOGFILE% 
echo %CHECKIN% %WORKING_DIR%\%SVN_REPOS%\%FILE% %COMMENT% %OPTIONS% >> %LOGFILE% 
echo ***** COMMENT_FILE ***** >> %LOGFILE% 
type %COMMENT_FILE% >> %LOGFILE% 2>&1 
echo . >> %LOGFILE% 
echo ************************ >> %LOGFILE% 
%CHECKIN% %WORKING_DIR%\%SVN_REPOS%\%FILE% %COMMENT% %OPTIONS% >> %LOGFILE% 2>&1
echo =======================CHECKIN DONE========================= >> %LOGFILE%   
goto END   
:END 
echo %DATE% %TIME% >> %LOGFILE%   
echo ============================END============================= >> %LOGFILE%
ENDLOCAL

Replace the elements in [square brackets] in above file, and you are ready to go.

I Use Subversion 1.7.x, SVNServer (std Edition) and Siebel Tools 8.2.2.4

Note: Rename the source control batch file (eg. to svn_srcctrl.bat) as siebel will overwrite the srcctrl.bat file on patches and updates 🙁

Enjoy!

/Henrik